#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
#include <SoftwareSerial.h>

#define CE_PIN 7
#define CSN_PIN 8

#define ESP_RX 2
#define ESP_TX 3

char server [] = "rtupdate.wunderground.com";
char WEBPAGE [] = "GET /weatherstation/updateweatherstation.php?";
char ID [] = "INORTH1074";        //wunderground weather station ID
String PASSWORD  = "XXXXX";   // wunderground weather station password

const byte txAddress[5] = {'R', 'x', 'A', 'A', 'A'};

RF24 radio(CE_PIN, CSN_PIN);

struct package {
  float temperature ;
  float humidity ;
  float pressure ;
  float rainfall;
  int vaneheading;
  float anemospeed;
  float windgust;
};

struct package data;

bool newData = false;

float tempf = 0;
float tempc = 0;
float humidityraw = 0;
float dewpointf = 0;

float rainfallnow = 0;
float rainlast1 = 0;
float rainlast2 = 0;
float rainlast3 = 0;
float rainlast4 = 0;
float rainlast5 = 0;

float rain1h = 0;
float rain24h = 0;
float rain24hmm = 0;
int raincount24h = 128; // instead of calling UTC time, which is complicated, set this to the hour*6 + #10 minutes when the sketch was uploaded
float windspeedmph = 0;
float baromin = 0;
int winddir = 0;
float windgustmph = 0;

long startTime = 0;
unsigned char check_connection = 0;
unsigned char times_check = 0;

String AP = "XXXXX";
String PASS = "XXXXX";
int countTrueCommand;
int countTimeCommand;
boolean found = false;

SoftwareSerial esp8266Module(ESP_RX, ESP_TX); // RX, TX ESP8266

//===========

void setup() {

  Serial.begin(9600);
  esp8266Module.begin(9600);
  sendCommand("AT", 5, "OK");
  sendCommand("AT+CWMODE=1", 5, "OK");
  sendCommand("AT+CWJAP=\"" + AP + "\",\"" + PASS + "\"", 20, "OK");

  radio.begin();
  radio.setDataRate( RF24_250KBPS );
  radio.openReadingPipe(1, txAddress);
  radio.setPALevel(RF24_PA_HIGH);

  radio.startListening();
  Serial.println("Receiver Starting Listening");

}

//=============

void loop() {
  getData();
  showData();
}

//==============

void getData() {
  if ( radio.available() ) {
    radio.read(&data, sizeof(data));
    newData = true;
    if (newData == true) {
      convertData ();
    }
  }
}

void showData() {
  if (newData == true) {
    Serial.println(data.temperature);
    Serial.println(data.humidity);
    Serial.println(data.pressure);
    Serial.println(data.rainfall);
    Serial.println(data.vaneheading);
    Serial.println(data.anemospeed);
    Serial.println(data.windgust);
    Serial.println("");
    newData = false;
  }
}

void wunderground()
{
  String cmd1 = "AT+CIPSTART=\"TCP\",\"";
  cmd1 += "rtupdate.wunderground.com"; // wunderground
  cmd1 += "\",80";
  esp8266Module.println(cmd1);

  if (esp8266Module.find("Error")) {
    Serial.println("AT+CIPSTART error");
    return;
  }

  if (newData == true) {
    String cmd = "GET /weatherstation/updateweatherstation.php?ID=";
    cmd += ID;
    cmd += "&PASSWORD=";
    cmd += PASSWORD;
    cmd += "&dateutc=now&winddir=";
    cmd += winddir;
    cmd += "&windspeedmph=";
    cmd += windspeedmph;
    cmd += "&windgustmph=";
    cmd += windgustmph;
    cmd += "&tempf=";
    cmd += tempf;
    cmd += "&dewptf=";
    cmd += dewpointf;
    cmd += "&humidity=";
    cmd += humidityraw;
    cmd += "&baromin=";
    cmd += baromin;
    cmd += "&rainin=";
    cmd += rain1h;
    cmd += "&dailyrainin=";
    cmd += rain24h;
    cmd += "&softwaretype=Arduino-ESP8266&action=updateraw&realtime=1&rtfreq=30";   // &softwaretype=Arduino%20UNO%20version1
    cmd += "/ HTTP/1.1\r\nHost: rtupdate.wunderground.com:80\r\nConnection: close\r\n\r\n";

    cmd1 = "AT+CIPSEND=";
    cmd1 += String(cmd.length());
    esp8266Module.println(cmd1);
    if (esp8266Module.find(">")) {
      esp8266Module.print(cmd);
      Serial.println("Data send OK");
      delay(1000);
    }
    else {
      esp8266Module.println("AT+CIPCLOSE");
      Serial.println("Connection closed");
      Serial.println(" ");
    }
    delay(2500);
  }
}

void convertData() {
  tempc = data.temperature;
  tempf = (tempc * 9.0) / 5.0 + 32.0;
  humidityraw = data.humidity;
  dewpointf = (dewPoint(tempf, data.humidity));

  raincount24h++;
  if (raincount24h < 143) {
    //have to account for the fact that wunderground only counts precip > 0.25mm (0.01 in). the rg-11 is very sensitive, and the graphs look off otherwise
    if (data.rainfall > 0.25) {
      rainfallnow = data.rainfall;
    }
    else {
      rainfallnow = 0;
    }
    rain24hmm = rain24hmm + rainfallnow;
    rain24h = rain24hmm * 0.00393701;
    // theoretically this should be 0.039... but I think the RG-11 is putting out 10mm chunks. This could be fixed in the transmitter, but easier here.
  }
  else {
    raincount24h = 0;
    rain24h = 0;
  }
  rain1h = (rainfallnow + rainlast1 + rainlast2 + rainlast3 + rainlast4 + rainlast5) * 0.00393701;
  // theoretically this should be 0.039... but I think the RG-11 is putting out 10mm chunks. This could be fixed in the transmitter, but easier here.

  // move each rainfall amount forward by 1
  rainlast5 = rainlast4;
  rainlast4 = rainlast3;
  rainlast3 = rainlast2;
  rainlast2 = rainlast1;
  rainlast1 = rainfallnow;

  windspeedmph = data.anemospeed / 1.60934;
  windgustmph = data.windgust / 1.60934;
  winddir = data.vaneheading;
  baromin = (data.pressure) / 33.86;

  wunderground();
}

double dewPoint(double tempf, double humidityraw)
{
  double RATIO = 373.15 / (273.15 + tempf);  // RATIO was originally named A0, possibly confusing in Arduino context
  double SUM = -7.90298 * (RATIO - 1);
  SUM += 5.02808 * log10(RATIO);
  SUM += -1.3816e-7 * (pow(10, (11.344 * (1 - 1 / RATIO ))) - 1) ;
  SUM += 8.1328e-3 * (pow(10, (-3.49149 * (RATIO - 1))) - 1) ;
  SUM += log10(1013.246);
  double VP = pow(10, SUM - 3) * humidityraw;
  double T = log(VP / 0.61078); // temp var
  return (241.88 * T) / (17.558 - T);
}

void sendCommand(String command, int maxTime, char readReplay[]) {
  Serial.print(countTrueCommand);
  Serial.print(". at command => ");
  Serial.print(command);
  Serial.print(" ");
  while (countTimeCommand < (maxTime * 1))
  {
    esp8266Module.println(command);//at+cipsend
    if (esp8266Module.find(readReplay)) //ok
    {
      found = true;
      break;
    }

    countTimeCommand++;
  }

  if (found == true)
  {
    Serial.println("OYI");
    countTrueCommand++;
    countTimeCommand = 0;
  }

  if (found == false)
  {
    Serial.println("Fail");
    countTrueCommand = 0;
    countTimeCommand = 0;
  }

  found = false;
}